// Schachspiel WS 04/05
// Katharina Engelland 2005
// -------------------------------------------------------------------------------------------
#version 3.5;                        // benötigte POV-Ray-Version
 background {rgb <1,1,1>}            // Farbe des Hintergrundes
// -------------------------------------------------------------------------------------------    
     
#include "colors.inc" 
#include "textures.inc"      
#include "stones.inc"
#include "golds.inc"    
      
//--------------------------------------------------------------------------------------------------
// neu definierte Farben          
          
#declare mattweiss = texture { pigment { color rgb < 1, 1, 1> }  
          finish { ambient 0.6  diffuse 0.4  phong 0 reflection 0 roughness 0.8 crand 0.03} }

#declare schwarz = texture { pigment { color rgb < 0.1, 0.1, 0.1> }  
          finish { ambient 0.7  diffuse 0.5  phong 0.05 phong_size 15 reflection 0 roughness 0.8 crand 0.1} }          




//========================================================================================================                        
// Kameras 
//-----------------------

camera {location <14, 17, -18> look_at <0,0,0> angle 60   }     // Uebersicht von vorne rechts
//camera {location <-14, 10, -18> look_at <0,0,5> angle 60   }    // Uebersicht von vorne links
//camera {location <3, 5, 0> look_at <-4,0,0> angle 60   }     // Figuren graue Seite
//camera {location <-3, 5, 0> look_at <4,0,0> angle 60   }     // Figuren schwarze Seite
//camera {location <0, 30, 0> look_at <0,0,0> angle 40   }      // von oben
//camera {location <0, 2, 1> look_at <-5,0,3> angle 60   }        // Bauern, Springer, Turm
//camera {location <10, 8, 0> look_at <3.5,0.2,0> angle 45   }      // Figuren schwarze Seite von hinten
//camera {location <10, 5, 4> look_at <0,0,0> angle 40   }        // Fahne schwarz

//------------------------------------------------------------------------------------------- 
// Lichtquellen
//-------------------------------------------------------------------------------------------
light_source { <45,45,25> White}    
//light_source { <-10, 20, -30> White}
light_source { <-10,20, 0> Green spotlight point_at <7,0,0> radius 8 falloff 12}
light_source { <10,20, 0> Yellow spotlight point_at <-7,0,0> radius 8 falloff 12}


//===========================================================================================
    
// Boden und Waende
 
plane {<0, 1, 0>, -8 texture {Water}} 
plane {<0, 1, 0>, -7.95 texture {Clouds}}

sphere {<0,-8,0> 75 pigment {Bright_Blue_Sky}}
                              
// Tisch

 box {<10, 0, 7>, <-10,-1,-7> texture {T_Grnt10}}    // Tischplatte

cone {<9.25, -0.4, 6.25>, 0.75,<9.25, -8, 6.25>, 0.5 texture {T_Grnt10}} 
cone {<-9.25, -0.4, 6.25>, 0.75,<-9.25, -8, 6.25>, 0.5 texture {T_Grnt10}}
cone {<9.25, -0.4, -6.25>, 0.75,<9.25, -8, -6.25>, 0.5 texture {T_Grnt10}}
cone {<-9.25, -0.4, -6.25>, 0.75,<-9.25, -8, -6.25>, 0.5 texture {T_Grnt10}}   


// ------------------------------------------------------------------------------------------------------
// Fluesse
// ------------------------------------------------------------------------------------------------------

// Wassergraeben:                                                                       
                
union { 
   box {<-6.5, -0.4, -7.1 >,<-5.2, 0.2, 7.1>}     
   box {< 6.5, -0.4, -7.1 >,< 5.2, 0.2, 7.1>} 
    texture {Water}
       } 
union {
   cylinder {<6.7,0,-7>,<6.7,0,7>,0.2}
   cylinder {<5,0,-7>,<5,0,7>,0.2}
       texture {schwarz}
       }                    
       
union {
   cylinder {<-6.7,0,-7>,<-6.7,0,7>,0.2}
   cylinder {<-5,0,-7>,<-5,0,7>,0.2}
       texture {T_Stone9}
       }                                   
       
// Bruecken
difference {
 union {
  difference {
     cylinder {<-5.85,-1.5,1>,<-5.85,-1.5,-1>,2 }       
     cylinder {<-5.85,-1.5,1.1>,<-5.85,-1.5,-1.1>,1.9 }         
     texture {T_Stone9}    
    }    

  difference {
     cylinder {<5.85,-1.5,1>,<5.85,-1.5,-1>,2 }       
     cylinder {<5.85,-1.5,1.1>,<5.85,-1.5,-1.1>,1.9 } 
     texture {schwarz}             
    }    
   }
 box {<-8,-0.1,1.2>, <8,-4.2,-1.2>}
}  
 
  
// Wasserfaelle

union {
   box {<-6.5,0.2,-7.01>,<-5.2,-9,-7.3>} 
   box {<6.5,0.2,-7.01>,<5.2,-9,-7.3>}  
   box {<-6.5,0.2,7.01>,<-5.2,-9,7.3>}
   box {<6.5,0.2,7.01>,<5.2,-9,7.3>}   
   cylinder {<-6.5,-0.05,-7.1>,<-5.2,-0.05,-7.1>,0.25}
   cylinder {<6.5,-0.05,-7.1>,<5.2,-0.05,-7.1>,0.25}
   cylinder {<-6.5,-0.05,7.1>,<-5.2,-0.05,7.1>,0.25}
   cylinder {<6.5,-0.05,7.1>,<5.2,-0.05,7.1>,0.25}
     texture {Water} 
     }  
   

                                             
// =================================================================
// Schloesser   
// ------------------------------------------------------------------
// graues Schloss  
// ------------------------------------------------------------------------------------
 
// Tuerme

cylinder {<-9.25, 0, -3>, <-9.25, 2, -3>, 0.4 texture {T_Stone9}}  
cylinder {<-9.25, 0,  3>, <-9.25, 2,  3>, 0.4 texture {T_Stone9}}
cylinder {<-7.25, 0, -3>, <-7.25, 2, -3>, 0.4 texture {T_Stone9}}  
cylinder {<-7.25, 0,  3>, <-7.25, 2,  3>, 0.4 texture {T_Stone9}}  

cone {<-9.25, 2, -3,>, 0.5, <-9.25, 3, -3>, 0 texture {T_Stone9}}
cone {<-9.25, 2,  3,>, 0.5, <-9.25, 3,  3>, 0 texture {T_Stone9}}
cone {<-7.25, 2, -3,>, 0.5, <-7.25, 3, -3>, 0 texture {T_Stone9}}
cone {<-7.25, 2,  3,>, 0.5, <-7.25, 3,  3>, 0 texture {T_Stone9}}  

difference {
 union {
   box {<-9.245, 0, -3 >, <-9.255, 2, 3> texture {T_Stone9}}
   box {<-9.25, 0, -3.005>, <-7.25, 2, -2.995> texture {T_Stone9}} 
   box {<-9.25, 0,  3.005>, <-7.25, 2,  2.995> texture {T_Stone9}}

   difference {
    box {<-7.245, 0, -3 >, <-7.255, 2, 3>}
    union {
       sphere {<-7.25, 0.75, 0>, 0.5}
       box {<-7.24, 0, -0.5 >, <-7.26, 0.75, 0.5>}}
    texture {T_Stone9}}                                  // Vorderseite mit ausgeschnittenem Tor
   }
 
union{ 
 box {<-10,1.6,0.2>, <-7,2.1,-0.2>}
 box {<-10,1.6,0.2>, <-7,2.1,-0.2> translate <0,0,0.75>}
 box {<-10,1.6,0.2>, <-7,2.1,-0.2> translate <0,0,1.5>}
 box {<-10,1.6,0.2>, <-7,2.1,-0.2> translate <0,0,2.25>}
 
 box {<-10,1.6,0.2>, <-7,2.1,-0.2> translate <0,0,-0.75>}
 box {<-10,1.6,0.2>, <-7,2.1,-0.2> translate <0,0,-1.5>}
 box {<-10,1.6,0.2>, <-7,2.1,-0.2> translate <0,0,-2.25>} 
 
 box {<0.2, 1.6, 5>, <-0.2, 2.1, -5> translate <-7.8,0,0>}
 box {<0.2, 1.6, 5>, <-0.2, 2.1, -5> translate <-8.7,0,0>}

 }    
}  

box {<-9.25,0,-3>,<-7.25,0.05,3> texture {T_Grnt20}}   // Boden    

// Fahne:
  
union {
  cylinder {<0,2.9,0>,<0,4,0>,0.05 texture {T_Stone9}}
  box {< 0.01, 4, 0>, <-0.01 ,3.5,0.7> texture {Candy_Cane}}
   rotate <0,-55,0>
   translate <-7.25,0,-3>
  }   

// -------------------------------------------------------------------
// schwarzes Schloss
// ------------------------------------------------------------------------------------------     
                    
// Tuerme          

cylinder {< 9.25, 0, -3>, < 9.25, 2, -3>, 0.4 texture {schwarz}}
cylinder {< 9.25, 0,  3>, < 9.25, 2,  3>, 0.4 texture {schwarz}}
cylinder {< 7.25, 0, -3>, < 7.25, 2, -3>, 0.4 texture {schwarz}}
cylinder {< 7.25, 0,  3>, < 7.25, 2,  3>, 0.4 texture {schwarz}} 
   
cone {< 9.25, 2, -3,>, 0.5, < 9.25, 3, -3>, 0 texture {schwarz}}
cone {< 9.25, 2,  3,>, 0.5, < 9.25, 3,  3>, 0 texture {schwarz}}
cone {< 7.25, 2, -3,>, 0.5, < 7.25, 3, -3>, 0 texture {schwarz}}
cone {< 7.25, 2,  3,>, 0.5, < 7.25, 3,  3>, 0 texture {schwarz}} 


// Mauern   

difference {
 union {
  box {<9.245, 0, -3 >, <9.255, 2, 3> texture {schwarz}}
  box {<9.25, 0, -3.005>, <7.25, 2, -2.995> texture {schwarz}} 
  box {<9.25, 0,  3.005>, <7.25, 2,  2.995> texture {schwarz}}
  

  difference {
    box {< 7.245, 0, -3 >, <7.255, 2, 3>}
    union {
       sphere {<7.25, 0.75, 0>, 0.5}
       box {<7.24, 0, -0.5 >, <7.26, 0.75, 0.5>}}
    texture {schwarz}}                                   // Vorderseite mit ausgeschnittenem Tor
   }
 
union{ 
 box {<10,1.6,0.2>, <7,2.1,-0.2>}
 box {<10,1.6,0.2>, <7,2.1,-0.2> translate <0,0,0.75>}
 box {<10,1.6,0.2>, <7,2.1,-0.2> translate <0,0,1.5>}
 box {<10,1.6,0.2>, <7,2.1,-0.2> translate <0,0,2.25>}
 
 box {<10,1.6,0.2>, <7,2.1,-0.2> translate <0,0,-0.75>}
 box {<10,1.6,0.2>, <7,2.1,-0.2> translate <0,0,-1.5>}
 box {<10,1.6,0.2>, <7,2.1,-0.2> translate <0,0,-2.25>} 
 
 box {<0.2, 1.6, 5>, <-0.2, 2.1, -5> translate <7.8,0,0>}
 box {<0.2, 1.6, 5>, <-0.2, 2.1, -5> translate <8.7,0,0>}

 }    
}
                              
    
box {<9.25,0,-3>,<7.25,0.05,3> texture {T_Grnt20}}  // Boden       
 
 
// Fahne:

union {
  cylinder {<0,2.9,0>,<0,4,0>,0.05 texture {schwarz}}
  box {< 0.01, 4, 0>, <-0.01 ,3.5,0.7> texture {Blood_Marble}}
   rotate <0,-55,0>
   translate <7.25,0,3>
  }    
  
    
    
// =============================================================================================
    
// Schachbrett       
//--------------------------------------------------------------------------------------

#declare Schachteil =
union {
    box {<0,0,0>, <1,0.2,1> texture {schwarz} }    
    box {<1,0,0>, <2,0.2,1> texture {mattweiss}}
    box {<0,0,1>, <1,0.2,2> texture {mattweiss}}
    box {<1,0,1>, <2,0.2,2> texture {schwarz} }
    }    
    
union {
    object {Schachteil translate <0,0,0>}
    object {Schachteil translate <2,0,2>}
    object {Schachteil translate <0,0,2>}
    object {Schachteil translate <2,0,0>}
    object {Schachteil translate <-2,0,0>}
    object {Schachteil translate <-4,0,0>}
    object {Schachteil translate <-2,0,2>}
    object {Schachteil translate <-4,0,2>}
    object {Schachteil translate <-2,0,-2>}
    object {Schachteil translate <-2,0,-4>}
    object {Schachteil translate <-4,0,-2>}
    object {Schachteil translate <-4,0,-4>}
    object {Schachteil translate <0,0,-2>}
    object {Schachteil translate <2,0,-2>}
    object {Schachteil translate <0,0,-4>}
    object {Schachteil translate <2,0,-4>}
       }    
       
       
//=====================================================================    
// Rahmen               
// --------------------------------------------------------------------------------------
                       
// 3 Treppenstufen                     

union {
    box {<-4,0,1>, <-4.15, 0.15,-1>}
    box {<-4.15,0,1>, <-4.3, 0.1,-1>}
    box {<-4.3,0,1>, <-4.45, 0.05,-1>}
      texture {T_Stone9}
                }             
                
                
union {
    box {<4,0,1>, <4.15, 0.15,-1>}
    box {<4.15,0,1>, <4.3, 0.1,-1>}
    box {<4.3,0,1>, <4.45, 0.05,-1>}
      texture {schwarz}  
                 }                     
                 
// Seitenraender:      
// (Schwarzes Schloss)

difference {
  prism {
    linear_sweep                
    linear_spline
    -4,
    4,
    4, //Eckpunkte
    <0,0.2>, <0.45,0>, <0,0>,<0,0.2> 
    rotate <-90,0,0>
    translate <4,0,0> 
      }  
  prism {
    linear_sweep                
    linear_spline
    -1,
    1,
    4, //Eckpunkte
    <-0.01,0.3>, <0.5,-0.01>, <0.01,0.01>,<0.01,0.2> 
    rotate <-90,0,0>
    translate <4,0,0> }
    
     texture {PinkAlabaster}
  }  

// (graues Schloss)
                              
 difference {
  prism {
    linear_sweep                
    linear_spline
    -4,
    4,
    4, //Eckpunkte
    <0,-0.2>, <-0.45,0>, <0,0>,<0,-0.2> 
    rotate <90,0,0>
    translate <-4,0,0> 
      }  
  prism {
    linear_sweep                
    linear_spline
    -1,
    1,
    4, //Eckpunkte
    <0.01,-0.3>, <-0.5,0.01>, <-0.01,-0.01>,<-0.01,-0.2> 
    rotate <90,0,0>                               
    translate <-4,0,0> }
    
     texture {PinkAlabaster}   
  }                             
                               
// (Seite Wand)    

  prism {
    linear_sweep                
    linear_spline
    -4,
    4,
    4, //Eckpunkte
    <-0.2, 0>, <0,-0.45>, <0,0>,<-0.2, 0> 
    rotate <0,0,-90>
    translate <0,0, -4> 
      
    texture {PinkAlabaster} 
   }  

// (Seite offen)   

prism {
    linear_sweep                
    linear_spline
    -4,
    4,
    4, //Eckpunkte
    <0.2, 0>, <0,0.45>, <0,0>,<0.2, 0> 
    rotate <0,0,90>
    translate <0,0, 4> 
      
    texture {PinkAlabaster} 
   }                         
// =================================================================================
                                
                                
                                
                                
// Figuren graues Schloss
//=========================


// Bauern 
// ----------------------------------------------------------------------------------------------            
            
// Bauer        
# declare Bauer1 =   
union {
   union {                       // union von: Figur (sor), Arm (cone), Mistgabel (union, der Rest)
    sor {  
     11,
     < 0.75, -0.5>, 
     <  0.5,    0>,
     < 0.25,  0.5>,
     <  0.6,  0.6>,
     < 0.17,    2>,
     < 0.3 ,  2.2>,
     < 0.24, 2.45>,
     <  0.5,  2.5>,
     < 0.26,  2.6>,
     < 0.25,  2.8>,
     <  0.3,    3>  
     
      }
    cone {<0.1, 1.65, -0.1>, 0.03 < 0.7, 1.5, -0.5 >, 0.2} 
    sphere {<0.75, 1.5, -0.55>, 0.16}     
    texture {DMFWood6} 
      }          
                       
   cylinder {<0.75, 0, -0.55>, <0.75, 2, -0.55>, 0.05 texture {Yellow_Pine}}    // Stecken der Mistgabel
   union {
      cylinder {<0.5, 2, -0.3667>, < 1.0, 2, - 0.7333>, 0.04 } 
      cone {<0.5, 2, -0.3667>, 0.035 <0.5, 2.6, -0.3667>, 0 }
      cone {<0.75, 2, -0.55>, 0.035 <0.75, 2.6, -0.55>, 0 }
      cone {<1.0, 2, -0.7333>, 0.035 <1.0, 2.6, -0.7333>, 0 }
         texture {Brass_Metal}  }  
  scale <0.4, 0.4, 0.4>       
  rotate <0, 45, 0>     
  translate <0,0.2,0>
 }      
   
  
object {Bauer1 translate <-2.5,0, 3.5>} 
object {Bauer1 translate <-2.5,0, 2.5>}
object {Bauer1 translate <-2.5,0, 1.5>}
object {Bauer1 translate <-2.5,0, 0.5>}
object {Bauer1 translate <-2.5,0,-0.5>}
object {Bauer1 translate <-2.5,0,-1.5>}
object {Bauer1 translate <-2.5,0,-2.5>}
object {Bauer1 translate <-2.5,0,-3.5>}


// ------------------------------------------------------------------------------------------------                                                                              
// Tuerme  
//------------------------------------------------------------------------------------------------------ 


# declare Turm1 =
difference {
  sor {
     11, 
     <1.2, -0.5>,
     <1.2, 0.2>,
     <0.8, 0.3>,
     <1.2, 0.6>,
     <0.7, 1.2>,
     <0.9, 1.4>,
     <0.65, 1.6>,
     <0.6, 3.0>,
     <0.9, 3.3>,
     <0.85, 4.2>,
     <0.5, 4.3>   
     }
  union {
     cylinder {<0,3.8,0>, <0,4.5,0> 0.6}    
     box {<0.1,3.8,1>, <-0.1,4.5,-1>} 
     box {<1,3.8,0.1>, <-1,4.5,-0.1>} 
     box {<0.1,3.8,1>, <-0.1,4.5,-1> rotate <0,45,0>} 
     box {<1,3.8,0.1>, <-1,4.5,-0.1> rotate <0,45,0>}
     }        
     scale <0.3,0.3,0.3>
     texture {T_Stone9} 
     translate <0,0.2,0>
   }  
   
object {Turm1 translate <-3.5, 0,3.5 > }
object {Turm1 translate <-3.5, 0,-3.5 > }       


// ----------------------------------------------------------------------------------------------------
// SPRINGER
// -------------------------------------------------------------------------------------------------

#declare Springer1 = 
union {

  union {                                      // Beine und Fuesse der Huerde
    cylinder {<0, 0, 1.1>,<0,1.1,1.1> 0.1}
    cylinder {<0, 0, -1.1>,<0,1.1,-1.1> 0.1}       

    sphere {<0,0,1.1>, 0.25 }
    sphere {<0,0,-1.1>, 0.25 }
         
    texture {Soft_Silver}
     
   }
                
                                
  union {
    union{
      box {<0.05, 0.9, -1.2>, <-0.05,1.2,-0.9>}
      box {<0.05, 0.9, -1.2>, <-0.05,1.2,-0.9> translate <0,0,0.6>}
      box {<0.05, 0.9, -1.2>, <-0.05,1.2,-0.9> translate <0,0,1.2>}
      box {<0.05, 0.9, -1.2>, <-0.05,1.2,-0.9> translate <0,0,1.8>} 
        texture {mattweiss}       
     } 
         
    union{
      box {<0.05, 0.9, -0.9>, <-0.05,1.2,-0.6>}
      box {<0.05, 0.9, -0.9>, <-0.05,1.2,-0.6> translate <0,0,0.6>}
      box {<0.05, 0.9, -0.9>, <-0.05,1.2,-0.6> translate <0,0,1.2>}
      box {<0.05, 0.9, -0.9>, <-0.05,1.2,-0.6> translate <0,0,1.8>} 
      pigment {color Red}       
     } 
    }                                   
  
// Maennchen:

  union {
    sor {  
     9,
     < 0.25,  0.5>,
     <  0.6,  0.6>,
     < 0.17,    2>,
     < 0.3 ,  2.2>,
     < 0.24, 2.45>,
     <  0.5,  2.5>,
     < 0.26,  2.6>,
     < 0.25,  2.8>,
     <  0.3,    3>  
      translate <0,1.1,0>  }
    cylinder {<0.2, 1.5, 0.35>, <-1.2, 1.1, 0.5> 0.2}
    cylinder {<0, 1.5, -0.35>, <1.2, 1.1, -0.5> 0.2}    
    
    sphere {<0.2, 1.5, 0.35>, 0.2}
    sphere {<0, 1.5, -0.35>, 0.2}  
    
    cone {<-1.2, 1.1, 0.5>, 0.2 <-1.3, 1.1, 0.5>, 0.3} 
    cone {< 1.2, 1.1,-0.5>, 0.2 < 1.3, 1.1,-0.5>, 0.3}
      
     
       texture {DMFWood6}
    }                    
    scale <0.4,0.4,0.4> 
    rotate <0,180,0>    
    translate <0,0.2,0>
  }  
  
object {Springer1 translate <-3.5,0,2.5>}  
object {Springer1 translate <-3.5,0,-2.5>}
                                                      
                                                      
// --------------------------------------------------------------------------------------------------                                                      
// Laeufer                                 
// --------------------------------------------------------------------------------------------------

#declare Laeufer1 =
union {  
 union {                       // union von: Figur (sor), Arm (cone)
    sor {  
     7,
     < 0.25,  0.6>,
     <  0.5,  0.7>,
     < 0.17,    2>,
     < 0.3 ,  2.2>,
     < 0.24, 2.45>,
     < 0.1,  2.6>,
     < 0.1,  2.8>
      
     }
     
     union {                                                 // vorderer Arm
        cylinder {<0,1.65,-0.1>, <0.1,1.3,-0.4> 0.2 }  
        sphere   {<0.1,1.3,-0.4>, 0.175} 
        cylinder {<0.1,1.3,-0.4>, <0.55,1.3,-0.4> 0.15} 
        
                                                        // hinterer Arm
        cylinder {<0,1.65,0.1>, <-0.4,1.4,0.4> 0.2 }  
        sphere   {<-0.4,1.4,0.4>, 0.175} 
        cylinder {<-0.4,1.4,0.4>, <0,1.2,0.6> 0.15}
                                                     // vorgestrecktes Bein
        sphere {<0,0.7,0.2> , 0.15}
        cylinder {<0,0.7,0.2>, <0.4,0.1,0.2>, 0.15}  
        cone {<0.4,0.1,0.2>, 0.15 <0.45,0.05,0.2>, 0.3}
                                                   // hinteres Bein
        sphere {<0,0.7,-0.2> , 0.15}
        cylinder {<0,0.7,-0.2>, <-0.4,0.2,-0.2>, 0.15}  
        cone {<-0.4,0.2,-0.2>, 0.15 <-0.45,0.15,-0.2>, 0.3} 
         }      
             
    texture {DMFWood6} 
   }          
      
     
     sor {
       4, 
       <0.24, 2>,
       <0.29, 2.3>,
       <0.24, 2.45>,
       <0, 2.6>              
                     
     pigment {color Red} } 
     
    scale <0.55,0.55,0.55>    
    translate <0,0.2,0>
 }  
 
object {Laeufer1 translate <-3.5,0,1.5>}            
object {Laeufer1 translate <-3.5,0,-1.5>}          


// ------------------------------------------------------------------------------------------------
// DAME
// ------------------------------------------------------------------------------------------------

// Krone:


#declare Dreieck =
  
 prism {
   linear_sweep linear_spline
   -3,
   3,
   4,
   <0,0>, <0,0.2>, <0.2,0>, <0,0>
   
   rotate <90,0,135>
   translate < 0,0.4,0> 
  }                     


#declare Kronennegativ =
 union {
   object {Dreieck rotate <0, 0,0>}
   object {Dreieck rotate <0, 10,0>}
   object {Dreieck rotate <0, 20,0>}
   object {Dreieck rotate <0, 30,0>}
   object {Dreieck rotate <0, 40,0>}
   object {Dreieck rotate <0, 50,0>}
   object {Dreieck rotate <0, 60,0>}
   object {Dreieck rotate <0, 70,0>}
   object {Dreieck rotate <0, 80,0>}
   object {Dreieck rotate <0, 90,0>}
   object {Dreieck rotate <0, 100,0>}
   object {Dreieck rotate <0, 110,0>}
   object {Dreieck rotate <0, 120,0>}
   object {Dreieck rotate <0, 130,0>}
   object {Dreieck rotate <0, 140,0>}
   object {Dreieck rotate <0, 150,0>}
   object {Dreieck rotate <0, 160,0>}
   object {Dreieck rotate <0, 170,0>} 
 }
                                      
                                      
#declare Krone =                                                                             
  
difference {
  union {  
   difference {
    cone {<0,0,0>, 1 <0,0.5,0>,1.15}
    cone {<0,-0.1,0>, 0.9 <0,0.6,0>, 1.15}
        
    }    }

    Kronennegativ
    
  texture {Gold_Metal} 
 }                                   
 
 
// Dame : 
 
#declare Dame1 =
union{
  sor {
     12, 
     <  1, -0.5>, 
     <  1,   0>,
     <0.9, 0.25>,
     <0.5, 0.4>,
     <0.45, 0.75>,
     <1.5, 0.9>,
     <0.5, 2.7>,
     <0.45, 3.2>,
     <0.7, 3.6>,
     <0.2, 4.2>,
     <0.2, 4.4>,
     <0.15, 4.9>
     texture {Candy_Cane}
   }       
   
   sphere {<0, 5,0>, 0.6 scale <0.9, 1, 1> texture {DMFWood6}} 
   
   object {Krone scale <0.5,1,0.5> translate <0,5.2,0>}
   scale <0.35,0.35,0.35>
   translate <0,0.2,0>   
 }       
 
object {Dame1 translate <-3.5,0, -0.5>}         


// --------------------------------------------------------------------------------------------
// Koenig
// --------------------------------------------------------------------------------------------

// Krone Koenig: 


#declare DreieckKoenig =
  
  prism {
   linear_sweep linear_spline
   -3,
   3,
   4,
   <-0.2,-0.2>, <0,0.5>, <0.5,0>, <-0.2,-0.2>
   
   texture {schwarz}
   rotate <90,0,135>
   translate < 0,0.7,0> 
 }                     


#declare KronennegativKoenig =
 union {
   object {DreieckKoenig rotate <0, 0,0>}
   object {DreieckKoenig rotate <0, 20,0>}
   object {DreieckKoenig rotate <0, 40,0>}
   object {DreieckKoenig rotate <0, 60,0>}
   object {DreieckKoenig rotate <0, 80,0>}
   object {DreieckKoenig rotate <0, 100,0>}
   object {DreieckKoenig rotate <0, 120,0>}
   object {DreieckKoenig rotate <0, 140,0>}
   object {DreieckKoenig rotate <0, 160,0>}
 }
                                                                          

#declare KroneKoenig =                                                                             
  
difference {
  union {  
   difference {
    cone {<0,0,0>, 1 <0,0.9,0>,1.15}
    cone {<0,-0.1,0>, 0.9 <0,1.1,0>, 1.15}
        
    }    }

    KronennegativKoenig
    
  texture {Gold_Metal} 
 }                                   
 
 


// Zepter:


#declare Zepter =
sor {
   13, 
   <0.2, -1>,
   <0.2,0>,
   <0.2,2>,
   <0.4,2.15>,
   <0.4,2.3>,
   <0.2,2.5>,
   <0.2, 3>,
   <0.4, 3.01>,
   <0.4, 3.1>
   <0.4, 3.2>,
   <0.2, 3.21>,
   <0.2, 3.5>,
   <0.1, 4>
   
   texture  {Gold_Metal} 
   scale <0.8,0.8,0.8>
   translate <1,0,0>} 


// Figur Koenig: 

# declare Koenig1 =
union{
 union {
  sor {
      11, 
     <  1, -0.5>, 
     <  1,   0>,
     <0.9, 0.25>,
     <0.5, 0.4>,
     <0.45, 0.75>,
     <1.3, 0.8>,
     <0.9, 2>,
     <1.1, 3.5>,
     <0.3, 4.2>,
     <0.3, 4.4>,
     <0.4, 5>
               }
     union {  
   cylinder {<0.2, 3.5,0.3>,<1.6,2.8,0> 0.3 }
   sphere  {<1.6,2.8,0>, 0.3} 
   cylinder {<1.6,2.8,0>, <1.3,2.5,-0.9>, 0.3}  
   cone   { <1.3,2.5,-0.9>, 0.3, <1.1, 2.4,-1.1,> 0.4  }  }             
       pigment {color Red}
   }  
     
   sphere {<0, 5,0>, 0.8 scale <0.9, 1, 1> texture {DMFWood6}} 
   object {KroneKoenig scale <0.5,1,0.5> translate <0,5.5,0>}
   object {Zepter rotate <10,20, -10>
                 translate <0,1.75,-0.40>} 
   translate <0,0.2,0>
   scale <0.35,0.35,0.35>
   rotate <0,225,0>   
 }
 
   
object {Koenig1 translate <-3.5,0,0.5> }                             
                                                      
                                                      
//======================================================================================

// Figuren Schwarzes Schloss
//===========================


// -----------------------------------------------------------------------------------------
// Bauern
// -----------------------------------------------------------------------------------------

 # declare Bauer2 =   
union {
   union {                       // union von: Figur (sor), Arm (cone), Mistgabel (union, der Rest)
    sor {  
     11,
     < 0.75, -0.5>, 
     <  0.5,    0>,
     < 0.25,  0.5>,
     <  0.6,  0.6>,
     < 0.17,    2>,
     < 0.3 ,  2.2>,
     < 0.24, 2.45>,
     <  0.5,  2.5>,
     < 0.26,  2.6>,
     < 0.25,  2.8>,
     <  0.3,    3>  
     
      }
    cone {<0.1, 1.65, -0.1>, 0.03 < 0.7, 1.5, -0.5 >, 0.2} 
    sphere {<0.75, 1.5, -0.55>, 0.16}     
    texture {EMBWood1} 
      }          
                       
   cylinder {<0.75, 0, -0.55>, <0.75, 2, -0.55>, 0.05 texture {Yellow_Pine}}    // Stecken der Mistgabel
   union {
      cylinder {<0.5, 2, -0.3667>, < 1.0, 2, - 0.7333>, 0.04 } 
      cone {<0.5, 2, -0.3667>, 0.035 <0.5, 2.6, -0.3667>, 0 }
      cone {<0.75, 2, -0.55>, 0.035 <0.75, 2.6, -0.55>, 0 }
      cone {<1.0, 2, -0.7333>, 0.035 <1.0, 2.6, -0.7333>, 0 }
         texture {New_Brass}  }  
  scale <0.4, 0.4, 0.4>       
  rotate <0, 225, 0>   
  translate <0,0.2,0>
 }
 
 
object {Bauer2 translate <2.5,0, 3.5>}
object {Bauer2 translate <2.5,0, 2.5>}
object {Bauer2 translate <2.5,0, 1.5>}
object {Bauer2 translate <2.5,0, 0.5>}
object {Bauer2 translate <2.5,0,-0.5>}
object {Bauer2 translate <2.5,0,-1.5>}
object {Bauer2 translate <2.5,0,-2.5>}
object {Bauer2 translate <2.5,0,-3.5>}


// ---------------------------------------------------------------------------------------------
// Tuerme
// ---------------------------------------------------------------------------------------------

# declare Turm2 =
difference {
  sor {
     11, 
     <1.2, -0.5>,
     <1.2, 0.2>,
     <0.8, 0.3>,
     <1.2, 0.6>,
     <0.7, 1.2>,
     <0.9, 1.4>,
     <0.65, 1.6>,
     <0.6, 3.0>,
     <0.9, 3.3>,
     <0.85, 4.2>,
     <0.5, 4.3>   
     }
  union {
     cylinder {<0,3.8,0>, <0,4.5,0> 0.6}    
     box {<0.1,3.8,1>, <-0.1,4.5,-1>} 
     box {<1,3.8,0.1>, <-1,4.5,-0.1>} 
     box {<0.1,3.8,1>, <-0.1,4.5,-1> rotate <0,45,0>} 
     box {<1,3.8,0.1>, <-1,4.5,-0.1> rotate <0,45,0>}
     }        
     scale <0.3,0.3,0.3>
     texture {schwarz}     
     translate <0,0.2,0>
   }  
   
object {Turm2 translate <3.5, 0,3.5 > }
object {Turm2 translate <3.5, 0,-3.5 > } 

 
// ------------------------------------------------------------------------------------------------- 
// Springer    
// -------------------------------------------------------------------------------------------------

#declare Springer2 = 
union {

  union {                                      // Beine und Fuesse der Huerde
    cylinder {<0, 0, 1.1>,<0,1.1,1.1> 0.1}
    cylinder {<0, 0, -1.1>,<0,1.1,-1.1> 0.1}       

    sphere {<0,0,1.1>, 0.25 }
    sphere {<0,0,-1.1>, 0.25 }
         
    texture {Soft_Silver}
     
   }
                
                                
  union {
    union{
      box {<0.05, 0.9, -1.2>, <-0.05,1.2,-0.9>}
      box {<0.05, 0.9, -1.2>, <-0.05,1.2,-0.9> translate <0,0,0.6>}
      box {<0.05, 0.9, -1.2>, <-0.05,1.2,-0.9> translate <0,0,1.2>}
      box {<0.05, 0.9, -1.2>, <-0.05,1.2,-0.9> translate <0,0,1.8>} 
        texture {mattweiss}       
     } 
         
    union{
      box {<0.05, 0.9, -0.9>, <-0.05,1.2,-0.6>}
      box {<0.05, 0.9, -0.9>, <-0.05,1.2,-0.6> translate <0,0,0.6>}
      box {<0.05, 0.9, -0.9>, <-0.05,1.2,-0.6> translate <0,0,1.2>}
      box {<0.05, 0.9, -0.9>, <-0.05,1.2,-0.6> translate <0,0,1.8>} 
      pigment {color Red}       
     } 
    }                                   
  
// Maennchen:

  union {
    sor {  
     9,
     < 0.25,  0.5>,
     <  0.6,  0.6>,
     < 0.17,    2>,
     < 0.3 ,  2.2>,
     < 0.24, 2.45>,
     <  0.5,  2.5>,
     < 0.26,  2.6>,
     < 0.25,  2.8>,
     <  0.3,    3>  
      translate <0,1.1,0>  }
    cylinder {<0.2, 1.5, 0.35>, <-1.2, 1.1, 0.5> 0.2}
    cylinder {<0, 1.5, -0.35>, <1.2, 1.1, -0.5> 0.2}    
    
    sphere {<0.2, 1.5, 0.35>, 0.2}
    sphere {<0, 1.5, -0.35>, 0.2}  
    
    cone {<-1.2, 1.1, 0.5>, 0.2 <-1.3, 1.1, 0.5>, 0.3} 
    cone {< 1.2, 1.1,-0.5>, 0.2 < 1.3, 1.1,-0.5>, 0.3}
      
     
       texture {EMBWood1}
    }                    
    scale <0.4,0.4,0.4>     
    translate <0,0.2,0>
    
  } 
  
object {Springer2 translate <3.5,0,2.5>}  
object {Springer2 translate <3.5,0,-2.5>}    
  
  
// ------------------------------------------------------------------------------------------------
// Laeufer                                 
// ------------------------------------------------------------------------------------------------

#declare Laeufer2 =
union {  
 union {                       // union von: Figur (sor), Arm (cone)
    sor {  
     7,
     < 0.25,  0.6>,
     <  0.5,  0.7>,
     < 0.17,    2>,
     < 0.3 ,  2.2>,
     < 0.24, 2.45>,
     //<  0.5,  2.5>,
     < 0.1,  2.6>,
     < 0.1,  2.8>
     //<  0.3,    3>  
     }
     
     union {                                                // vorderer Arm
        cylinder {<0,1.65,-0.1>, <0.1,1.3,-0.4> 0.2 }  
        sphere   {<0.1,1.3,-0.4>, 0.175} 
        cylinder {<0.1,1.3,-0.4>, <0.55,1.3,-0.4> 0.15} 
        
                                                           // hinterer Arm
        cylinder {<0,1.65,0.1>, <-0.4,1.4,0.4> 0.2 }  
        sphere   {<-0.4,1.4,0.4>, 0.175} 
        cylinder {<-0.4,1.4,0.4>, <0,1.2,0.6> 0.15}
                                                           // vorgestrecktes Bein
        sphere {<0,0.7,0.2> , 0.15}
        cylinder {<0,0.7,0.2>, <0.4,0.1,0.2>, 0.15}  
        cone {<0.4,0.1,0.2>, 0.15 <0.45,0.05,0.2>, 0.3}
                                                           // hinteres Bein
        sphere {<0,0.7,-0.2> , 0.15}
        cylinder {<0,0.7,-0.2>, <-0.4,0.2,-0.2>, 0.15}  
        cone {<-0.4,0.2,-0.2>, 0.15 <-0.45,0.15,-0.2>, 0.3} 
         }      
             
    texture {EMBWood1} 
   }          
      
     
     sor {
       4, 
       <0.24, 2>,
       <0.29, 2.3>,
       <0.24, 2.45>,
       <0, 2.6>              
                     
     pigment {color Blue} } 
     
    rotate <0,180,0>
    scale <0.55,0.55,0.55>   
    translate <0,0.2,0>
 }  
 
object {Laeufer2 translate <3.5,0,1.5>}            
object {Laeufer2 translate <3.5,0,-1.5>}       





// -------------------------------------------------------------------------------------------------
// DAME 
// -------------------------------------------------------------------------------------------------

 
#declare Dame2 =
union{
  sor {
     12, 
     <  1, -0.5>, 
     <  1,   0>,
     <0.9, 0.25>,
     <0.5, 0.4>,
     <0.45, 0.75>,
     <1.5, 0.9>,
     <0.5, 2.7>,
     <0.45, 3.2>,
     <0.7, 3.6>,
     <0.2, 4.2>,
     <0.2, 4.4>,
     <0.15, 4.9>
     texture {Blood_Marble}
   }       
   
   sphere {<0, 5,0>, 0.6 scale <0.9, 1, 1> texture {EMBWood1}} 
   
   object {Krone scale <0.5,1,0.5> translate <0,5.2,0>}
   scale <0.35,0.35,0.35>
   translate <0,0.2,0>   
 }       
 
object {Dame2 translate <3.5,0, -0.5>}   




// --------------------------------------------------------------------------------------------------
// Koenig
// --------------------------------------------------------------------------------------------------



// Figur Koenig: 

# declare Koenig2 =
union{
 union {
  sor {
      11, 
     <  1, -0.5>, 
     <  1,   0>,
     <0.9, 0.25>,
     <0.5, 0.4>,
     <0.45, 0.75>,
     <1.3, 0.8>,
     <0.9, 2>,
     <1.1, 3.5>,
     <0.3, 4.2>,
     <0.3, 4.4>,
     <0.4, 5>
               }
     union {  
   cylinder {<0.2, 3.5,0.3>,<1.6,2.8,0> 0.3 }
   sphere  {<1.6,2.8,0>, 0.3} 
   cylinder {<1.6,2.8,0>, <1.3,2.5,-0.9>, 0.3}  
   cone   { <1.3,2.5,-0.9>, 0.3, <1.1, 2.4,-1.1,> 0.4  }  }             
       pigment {color Gray50}
   }  
     
   sphere {<0, 5,0>, 0.8 scale <0.9, 1, 1> texture {EMBWood1}} 
   object {KroneKoenig scale <0.5,1,0.5> translate <0,5.5,0>}
   object {Zepter rotate <10,20, -10>
                 translate <0,1.75,-0.40>} 
   translate <0,0.2,0>
   scale <0.35,0.35,0.35>
   rotate <0,80,0>   
 }
 
   
object {Koenig2 translate <3.5,0,0.5> }