// Darstellung einer Dini-Fläche durch ihre Parameterdarstellung
// A. Filler, Humboldt-Universitaet zu Berlin, 2002
// ---------------------------------------------------------------
#version 3.5;                         // benötigte POV-Ray-Version
#include "colors.inc"                 // Defintion der Farben
background {White}                    // Farbe des Hintergrundes

// Parameterdarstellung der Konischen Spirale
//   ("parametric object")
parametric {
  function {cos(u)*sin(v)}
  function {sin(u)*sin(v)}
  function {cos(v)+ln(tan(v/2))+0.2*u}
  <0,0.001>,<4*pi,2>                        // Intervall für u und v
  contained_by { box { <-3,-3,-3>, <3,3,3> } }  
  max_gradient 3   accuracy 0.001          // Berechnungsparameter
  precompute 18 x,y,z                       // Berechnungsparameter
 texture{ pigment{rgb<0.4,0.4,0.4>} 
    finish{ ambient 0.4  diffuse 0.6  phong 0.5  reflection 0.1}    } 
rotate<-120,180,0>
}

// Definition der Kamera und der Lichtquellen

#declare camera_position = <0,-10,40> ;  

camera { location  camera_position
         angle 12
         look_at   <0.0, 0.0, 0.5> 
}
light_source { <-50, 80, 200>  color rgb <1, 1, 1> }
light_source { <0,100,20>  color rgb <1, 1, 1> }
light_source { camera_position   color rgb <0, 0, 1>}